( Utilitaire pour visualisation du contenu de la memoire.
  Version 1.01 du 1er Octobre 2000.
  Ecrit par jpb.forth .
)

TELECHARGEMENT 

( Visualisation de la memoire a partir de l'adresse et sur la longueur specifiees:
  adresse,longueur DUMP - 
)

HEX 

: DUMP
 BASE @ >R HEX
 ." Adresses 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F 0123456789ABCDEF"
 BEGIN
  CR DUP
 WHILE
  OVER >R >R FFFFFFF0 AND R>
  0 <# DROP 3 PICK # # # # # # # # #> TYPE SPACE
  OVER OVER 10
  BEGIN
   3 PICK R@ U<
   IF
    3 SPACES
   ELSE
    OVER
    IF
     3 PICK C@ FF AND <# # # #> TYPE SPACE >R 1- R>
    ELSE
     3 SPACES
    THEN
   THEN
   >R >R 1+ R> R> 1- DUP 0=
  UNTIL
  DROP DROP DROP 10
  BEGIN
   3 PICK R@ U<
   IF
   SPACE
   ELSE
    OVER
    IF
     3 PICK C@ DUP 20 < OVER 7E > OR
     IF
      DROP 2E
     THEN
     EMIT >R 1- R>
    ELSE
     SPACE
    THEN
   THEN
   >R >R 1+ R> R> 1- DUP 0=
  UNTIL
  DROP R> DROP DUP
  IF
   OVER FF AND 0=
   IF
    CR ." ESCAPE pour arreter ou une autre touche pour continuer." KEY 1B =
    IF
     DROP 0
    THEN
   THEN
  THEN
 REPEAT
 R> BASE ! DROP DROP
;

DECIMAL

( FIN
)