( Utilitaire pour evaluation d'une nouvelle version du noyau.
  Version 1.10 du 2 Fevrier 2002.
  Ecrit par jpb.forth .
)

TELECHARGEMENT 

( Transfert du terminal vers le mini systeme FORTH:
  adresse XMODEM_RECOIT - 
)

DECIMAL 

: INPUT_FILE? ( - --> nb_octets )
 INPUT_FILE DUP @ SWAP 2+ @ - 255 AND
;

: XMODEM_RECOIT
 ." Envoyer le fichier vXXX_128.bin sous protocole XMODEM." CR 255 SWAP
 BEGIN
  2000 TEMPO INPUT_FILE? DUP
  IF
   DUP 0 DO
    KEY DROP
   LOOP
  THEN
  0=
 UNTIL
 0
 BEGIN
  KEYBOARD
  IF
   -1
  ELSE
   1- DUP 0<
   IF
    21 EMIT 100+
   THEN
   100 TEMPO 0
  THEN
 UNTIL
 DROP
 BEGIN
  KEY DUP 1 =
  IF
   KEY DUP 255 AND >R + KEY + OVER 128+ 3 PICK DO
    KEY DUP I C! + 
   LOOP
   KEY - 255 AND
   IF
    21 EMIT
   ELSE
    OVER R@ = NOT
    IF
     SWAP DROP R@ SWAP 128+ 6 EMIT
    THEN
   THEN
   R> DROP 0
  ELSE
   DUP 4 = 
   IF
    DROP 6 EMIT -1
   ELSE
    24 =
    IF
     -1
    ELSE
     1000 TEMPO INPUT_FILE? ?DUP
     IF
      0 DO
       KEY DROP
       LOOP
    THEN
     21 EMIT 0
    THEN
   THEN
  THEN
 UNTIL
 DROP DROP
;

HEX

: PROCEDURE
 ." Si une EEPROM I2C est presente sur la carte, elle doit etre effacee.
La carte doit sortir d'un RESET.
Ces 2 conditions sont-elles reunies -o/n- ? "
 BEGIN
  KEY DUP 4F = OVER 6F = OR
  IF
   DROP ." OUI" CR 20000 DUP XMODEM_RECOIT 400 TEMPO DUP 6+ @ + EXECUTE
  ELSE
   DUP 4E = SWAP 6F = OR
   IF
    ." NON" CR ." Alors effacez l'EEPROM I2C, reinitialisez la carte et recommencez. " -1
   ELSE
    BELL 0
   THEN
  THEN
 UNTIL
;

PROCEDURE

( FIN
)